#                                               -*- Autoconf -*-
# Process this file with autoconf to produce a configure script.

AC_PREREQ(2.59)
AC_INIT(PCP_Utilities, 1.0, heber@ins.uni-bonn.de)
AC_CONFIG_SRCDIR([CreateGaAs.c])
AC_CONFIG_HEADER([config.h])

AM_INIT_AUTOMAKE

# Checks for programs.
AC_PROG_AWK
AC_PROG_CXX
AC_PROG_CC
AM_MISSING_PROG([DOXYGEN], [doxygen])

# Checks for libraries.
AC_CHECK_LIB(m, sqrt, ,AC_MSG_ERROR([compatible libc math library not found]))

# Checks for header files.
AC_HEADER_STDC
AC_CHECK_HEADERS([stdlib.h string.h])

# Checks for typedefs, structures, and compiler characteristics.
AC_C_CONST
AC_TYPE_SIZE_T

# debugging info
AC_ARG_ENABLE([debug],AS_HELP_STRING([--enable-debug],[Output debugging information, argument is yes or debugging level (default is no).]),
              [enable_debug=$enableval], [enable_debug=no])
if ! test x"$enable_debug" = xno; then
	if test x"${enable_debug}" = xyes; then
		CFLAGS="-g3"
		CXXFLAGS="-g3"
	else
		CFLAGS="-g${enable_debug}"
		CXXFLAGS="-g${enable_debug}"
	fi
  AC_DEFINE(HAVE_DEBUG,1, ["Output debugging info"])
  AC_SUBST(HAVE_DEBUG)
fi

# optimization level
AC_ARG_ENABLE([optimization],AS_HELP_STRING([--enable-optimization],[Optimization level of compiler. Argument is yes or debugging level. (default is 2)]),
              [enable_optimization=$enableval], [enable_optimization=yes])
if test ! x"$enable_optimization" = xno; then
	if test x"$enable_debug" = xno; then
		if test x"${enable_optimization}" = xyes; then
			CFLAGS="-O2"
			CXXFLAGS="-O2"
		else
			CFLAGS="-O${enable_optimization}"
			CXXFLAGS="-O${enable_optimization}"
		fi
#	else
#		AC_MSG_WARN(["Already specified --enable-debug!"])
	fi
fi

# Checks for library functions.
AC_FUNC_MALLOC
AC_FUNC_REALLOC

# test suite
AC_CONFIG_TESTDIR(tests)
AC_CONFIG_FILES([tests/atlocal tests/Makefile])
AC_CONFIG_FILES([tests/NanoCreator], [chmod +x tests/NanoCreator])

AC_CHECK_FUNCS([pow sqrt strchr strrchr strstr])
AC_CONFIG_FILES([Makefile doc/Makefile])
AC_CONFIG_FILES([CreateFromXYZ.sh dynamicANOVA.sh Nanotubes.pl ReSequenceDX.pl])
AC_OUTPUT